label crime:
    play music "/audio/Danger.mp3"
    "\"C'est affreux !\""
    "\"Qui a pu faire ça ?\""
    scene bg hall with dissolve
    "Les élèves et les professeurs sont terriblement choqués par le corps sans vie d'un professeur qui a été laissé près des casiers."
    "La professeure a été mutilée !"
    "Magiquement mutilée. Mais le spectacle est quand même atroce."
    "Des champignons sortent des narines."
    "Des racines émergent des oreilles."
    "Les cheveux ne retombent pas et flottent en l'air."
    "Une troisième jambe est présente. Elle commence depuis le milieu du dos !"
    "Et puis son visage est bleu. Elle a été étranglée."
    
    shermie "Du calme ! Du calme !"
    shermie "Au vu de ce terrible événement, les cours seront annulés pour cet après-midi."
    shermie "Vous devez aller dans vos chambres jusqu'à ce que la vérité soit faite sur ce meurtre !"
    shermie "N'ayez aucune crainte, les cantinières vous apporteront votre repas."
    shermie "Il est désormais strictement interdit de sortir de vos chambres sauf si vous avez une urgence. Je veillerai à vous accompagner."
    "\"Qui est-ce ?\""
    "\"J'ai peur ! Appelez la police !\""
    "Les élèves sont tiraillés entre la curiosité et la peur."
    shermie "Alors. Je vais vous dire qui elle était. Juliette Aderneau Gony, ou Juliette A. Gony."

    if ami_choisi == "Caswell":
        caswell "(Capo Era, Juliette A. Gony ; qu'est-ce que c'est que ces noms ! Mais au moins la pauvre Gony portait un nom qui lui était prémonitoire.)"
        connor "(Caswell doit être en train de faire un commentaire méchant sur le nom absurde de Madame Gony. C'est à la fois vilain... et drôle.)"

    shermie "Allez ! Éloignez-vous ! Les couloirs sont dangereux !"
    "Tous les élèves se dirigent vers leurs chambres. Ce fait divers tragique sera dans toutes les conversations."

    if ami_choisi == "Caswell":
        "Connor part vers les chambres. Caswell le suit, mal à l'aise. Il a beau être un nerd introverti, il a du mal à cacher son angoisse."
    else:
        "Les chambres ne sont pas mixtes. Connor ne pourra pas discuter avec [ami_choisi] à propos de ce meurtre."

    stop music fadeout 2.0
    pause 2.0
    scene bg dortoir with dissolve

    if ami_choisi == "Caswell":
        connor "Caswell ? Ça va ? T'es tout pâle."
    else:
        "Connor constate que le nerd qui est dans sa classe n'est pas dans son assiette."
        connor "Hé. Ça va ?"

    "Un élève de la classe de Connor s'approche des deux garçons."
    connor "Hé toi. Tu ne serais pas dans notre classe ?"
    erick "Tu as l'oeil, rouquin. Erick Forburgh est mon nom."
    menu:
        connor "Un garçon de 12 ans avec les cheveux teints en gris ; ça ne se rate pas."
        "Ça te donne un air \"adulte\"":
            erick "C'est le but escompté."
        "Boodlord n'est pas une école de cosplayers !":
            erick "Toi. Tu vas voir."
            play sound "/audio/Gifle.mp3"
            scene bg dortoir with hpunch
            "POUM !"
            "Connor a reçu un coup de paume sur le milieu du front !"

    erick "\"Sarouel\" ? T'es OK ?"
    caswell "Vous allez peut-être me considérer comme paranoïaque mais Boodlord est devenu le bunker de la mort ! On pourrait être les prochains ! Il faut partir d'ici !"
    erick "Euh ? Allô ? Pour information, nous sommes sur l'archipel des Samoa ! C'est même pas la peine de fuir à la nage !"
    connor "Il ne prévoit pas de quitter l'île ! Il veut juste quitter la grotte de Boodlord ! Et tu trouves pas ça bizarre qu'on soit confinés dans nos chambres plutôt que de partir de Boodlord ?"

    if ami_choisi == "Caswell":
        caswell "Connor... Pars avec moi... Erick, rejoins-nous..."
        connor "Je pars avec toi. Amis à la vie, à la mort !"
        jump evasion
    else:
        caswell "Venez avec moi... Je veux pas partir tout seul..."
        menu:
            connor "(Est-ce qu'il faut vraiment partir d'ici ?)"
            "\"Oui, le meurtrier pourrait récidiver !\"":
                connor "Caswell, je viens avec toi."
                erick "Moi aussi. Vous n'êtes pas assez forts pour n'y aller qu'à deux."
                "Cette remarque d'Erick était un mélange d'empathie et de mésestime de ses camarades."
                jump evasion
            "\"Non, il faut arrêter le meurtrier !\"":
                "Désolé, mais cette branche du scénario n'a pas encore été écrite ! Le choix est considéré comme \"Oui\"."
                "Mais pas de problème, vous aurez droit à un scénario alternatif pour la prochaine version !"
                jump evasion