label scene_1:
    # Viktor arrive face à l'école de danse et change d'identité avant d'entrer
    show viktor neutre at left with moveinleft
    v "L'école de danse d'Agnessa Danitchenko."
    v "Ancienne danseuse étoile, elle enseigne désormais sa passion pour le ballet."
    v "Cette école est réservée aux filles."
    v "Ce n'est pas très honnête de faire ça, mais je vais mentir en disant que je suis une fille."
    v "Dans la vie quotidienne, on m'a souvent pris pour une fille à cause de ma morphologie plutôt fine et de mes cheveux mi-longs."
    v "Reste à trouver un alias à Viktor."
    v "... Hum..."
    v "Tamara. Je m'appellerai Tamara Verakova."
    t "Voilà. Je suis prête à entrer."
    scene bg accueil with fade
    jump scene_2

label scene_2:
    # Tamara entre et fait une démonstration satisfaisante devant Agnessa qui l'intègre à l'école
    show viktor neutre at left with moveinleft
    t "Bonjour ? Y a quelqu'un ?"
    show agnessa neutre at right with moveinright
    a "Jeune fille, bonjour."
    "Tamara est un peu déstabilisée devant l'ancienne danseuse étoile et peine à trouver ses mots."
    t "Madame, je voudrais m'inscrire..."
    a "Faites-moi une démonstration."
    t "(Quoi ? Une démonstration dès le début ?)"
    "Agnessa veut tester Tamara sur ses compétences. Tout le monde ne peut pas prétendre à recevoir des leçons de la part d'Agnessa Danitchenko !"
    "Tamara exécute quelques pointes et termine par un grand écart."
    a "Mmh. Pas mal, mademoiselle. J'ai vu mieux que ça mais vous vous en sortez bien pour une candidate."
    a "Comment vous appelez-vous ?"
    t "V...Tamara. Tamara Verakova. J'ai 16 ans."
    t "(J'ai failli faire sauter mon alias.)"
    a "Tamara. Votre prestation m'a convaincue. Vous avez encore des choses à apprendre mais je vous souhaite la bienvenue parmi nous."
    t "Madame, merci beaucoup."
    a "Votre premier cours aura lieu demain de 17 à 19 avec les autres danseuses. Vous veillerez à venir avec des vêtements pas trop amples."
    a "Vous penserez aussi à payer votre inscription et vos 10 premières heures. Vous me ferez un chèque de 20000 roubles."
    "Note du créateur" "20000 roubles valent environ 232 euros."
    t "Très bien, madame. À demain."
    hide viktor with dissolve
    scene bg izmailovo with fade
    jump scene_3

label scene_3:
    # Tamara sort de l'école et se demande quoi dire à ses parents au sujet de son absence
    show viktor neutre at left with moveinleft
    v "C'est inouï. J'ai réussi à convaincre une ancienne danseuse étoile de m'accepter dans ses cours !"
    v "Et en plus, elle n'a même pas remarqué qu'elle avait un garçon face à elle !"
    v "Mais un autre problème se présente. Je ne peux pas dire à maman que je suis allé me renseigner sur l'école de danse ! Il faut que j'invente un prétexte."
    hide viktor with moveoutleft
    "Viktor se dirige chez lui en ayant réfléchi à une version à donner."
    scene bg rdc with fade
    jump scene_4

label scene_4:
    # Tamara arrive chez elle
    show maman at left with dissolve
    pause 1.0
    show viktor neutre at right with moveinright
    m "Tu en as mis du temps pour revenir ! Où étais-tu ?"
    v "J'ai rejoint l'école d'échecs de l'autre côté de la ville. Il est dirigé par Monsieur Meryshev, mon professeur de maths."
    m "Tu t'intéresses aux échecs maintenant ?"
    v "L'inscription est payante par contre. Il me demande un chèque de 20000 roubles pour 20 heures de cours."
    m "C'est cher."
    v "Monsieur Meryshev est un bon joueur et un bon formateur. Il m'a dit que son classement Elo était autour de 2050."
    m "Un tel classement veut donc dire qu'il est un expert."
    v "C'est ça."
    m "Voilà, ton chèque est prêt."
    v "La prochaine séance aura lieu demain de 17 à 19."
    m "Tu mets la table ? Pavel a bientôt fini de préparer le repas."
    show maman at center with moveinleft
    show pavel at left with moveinleft
    p "C'est prêt ! Je suis sûr que vous aimerez mes pelmenis !"
    "Note du créateur" "Les pelmenis sont des ravioles farcies en forme d'oreille."
    v "(Pavel est le nouveau fiancé de maman. Il est passionné par la cuisine. Cela fait 8 mois qu'il s'est installé chez nous.)"
    v "(Il ne remplacera jamais papa mais il est très attentionné envers maman. Et il n'y a que ça qui compte: le bonheur de maman.)"
    m "Tu as fait vite quand même ! La table n'est pas encore mise !"
    p "Pas de problème, j'attendrai."
    hide pavel with moveoutleft
    pause 1.0
    hide maman with moveoutleft
    pause 1.0
    hide viktor with moveoutleft
    "Viktor et sa mère mettent la table ensemble. Les pelmenis de Pavel sont succulents. L'erreur la plus fréquente lorsqu'on cuisine des pelmenis est de trop les farcir."
    "Ça fait une sensation bizarre quand on avale une grosse quantité de viande d'un seul coup. Ballonnements assurés."
    "Après ce bon dîner, Viktor part dans sa chambre faire ses devoirs. Il a justement une paire d'exercices de maths à faire. Monsieur Meryshev est plutôt sévère quand il découvre que vous n'avez pas fait ses exercices."
    scene bg chambre with fade
    jump scene_5

label scene_5:
    # Viktor fait ses devoirs tranquillement et parle de Monsieur Meryshev
    # Viktor voudrait vérifier le chèque
    show viktor neutre at center with moveinright
    v "Monsieur Meryshev a tendance à donner des exercices plus difficiles que la normale. Il dit qu'il pourra plus se concentrer sur ceux qui ont des difficultés."
    v "Mais il a quel âge à peu près ? Pas plus de 30 ans à mon avis. En général, les jeunes professeurs sont sympathiques. Ils essaient même de faire ami-ami avec leurs élèves. Mais Monsieur Meryshev est tout l'inverse. Son mauvais caractère intimide un peu la classe."
    v "Si jamais une comédie musicale sur Blanche-Neige devait se produire, je verrais bien mon prof dans le rôle de Grincheux."
    "Viktor parvient à terminer ses exercices de probabilités sans trop de difficultés."
    menu:
        v "J'ai comme l'impression que je devrais tout de même vérifier le chèque..."
        "Vérifier":
            $ ordre_verifie = True
            v "Mmh..."
            v "Oh, bonne intuition !"
            v "L'ordre du chèque est à Monsieur Meryshev ! Si Madame Danitchenko découvre que l'ordre est faux, elle se posera des questions !"
            v "Il faut corriger ça."
            "Viktor prend son correcteur et remplace le nom de Monsieur Meryshev par celui d'Agnessa."
            v "C'est fait."
        "Ne rien faire":
            v "Peut-être que je me fais des idées."
    "La soirée se passe tranquillement. Viktor a cours demain. Juste après avoir terminé le lycée, il partira directement à l'école d'Agnessa pour son tout premier cours."
    scene bg izmailovo with fade
    jump scene_6

label scene_6:
    # Viktor arrive devant l'école et tente de faire connaissance avec les autres élèves
    # Dominika fait preuve de méchanceté et se moque de Viktor
    show viktor neutre at left with moveinleft
    t "(La journée au lycée s'est passée tranquillement. J'espère que les filles ne me démasqueront pas. Parce que si ça devait arriver, j'aurais de gros problèmes.)"
    t "(J'imagine leurs réactions: \"Ah mais y a un garçon parmi nous !\" ; \"Qu'est-ce qu'il fait là, lui !\" ; et pas que.)"
    t "(Si je me fais démasquer, je me ferai éjecter comme un imposteur dans Among Us.)"
    t "(J'exagère. Je risque au pire de me faire sortir à coups de pied dans le derrière.)"
    show dominika neutre at right with moveinright
    "Fille arrogante" "Hé."
    show dominika colere at right
    "Fille arrogante" "Hé !"
    t "Ah !"
    show dominika neutre at right
    "Fille arrogante" "Arrête de rêvasser, la nouvelle."
    t "Oh bonjour. Tu es aussi inscrite à l'école de Madame Danitchenko ?"
    "Fille arrogante" "Déjà, on l'appelle Agnessa."
    "Fille arrogante" "Et moi, on m'appelle Dominika ; ou Princesse Yurlova."
    show lucy colere at center with moveinleft
    "Autre fille" "Arrête de te prendre pour le centre du monde, Dominika !"
    show dominika colere at right
    d "Comment oses-tu me traiter d'arrogante, Lucy ! Tu mérites que je te brise les chevilles."
    t "(Quel caractère. Je devrais éviter de la provoquer.)"
    a "Mademoiselle Dominika ! Silence !"
    hide dominika with moveoutright
    hide lucy with moveoutright
    pause 1.0
    show agnessa neutre at right with moveinright
    t "(Agnessa vient d'arriver. Tant mieux, le calme va revenir.)"
    t "Agnessa, j'ai le chèque pour les frais d'inscription."
    if ordre_verifie == True:
        a "Merci, Mademoiselle Tamara."
    else:
        a "Pourquoi y a-t-il le nom d'un certain Monsieur Meryshev dans l'ordre ?"
        t "(Et fichtre. J'avais dit que c'était pour le club d'échecs de Monsieur Meryshev et maman a mis son nom ! J'aurais dû vérifier !)"
        t "À vrai dire, je suis également intéressée par le club d'échecs de Monsieur Meryshev. Et les frais d'inscription sont exactement les mêmes. Il y a juste le nombre d'heures de départ qui diffère."
        t "(Je retombe sur mes pattes.)"
        a "Ce n'est pas grave. Je corrigerai le chèque."
        t "Merci."
    a "Les filles, allez déposer vos effets personnels aux vestiaires."
    hide agnessa with moveoutright
    hide viktor with moveoutright
    scene bg vestiaire with fade
    jump scene_7

label scene_7:
    # Les filles se changent
    # Dominika critique l'apparence de Tamara
    show viktor neutre at left with moveinleft
    t "(Dominika se rapproche de moi. Je vais encore recevoir des mots \"gentils\" de sa part.)"
    show dominika neutre at right with moveinright
    d "La nouvelle. Tes jambes sont plutôt grosses. Ça te gênera pas dans tes chorégraphies ?"
    t "Agnessa a été satisfaite de ma démonstration hier. Donc non. Et aussi, je cours une heure chaque jour. C'est pour ça que mes jambes sont un peu musclées."
    d "Tes sourcils sont un peu épais. Tu es en fait un garçon déguisé en fille ou vice-versa ?"
    show viktor colere
    t "Et moi, je t'en pose des questions comme ça !"
    show dominika gifle
    play sound "/audio/Gifle.mp3"
    pause 0.1
    show dominika at chute
    "SLAP !"
    "Dominika n'a pas vu venir la gifle donnée par Tamara."
    show lucy neutre at center with moveinright
    l "Oh là. Tu n'aurais pas dû gifler Dominika ! Elle va aller tout de suite rapporter ça à Agnessa et tu risques d'être punie !"
    show dominika at relever
    d "Elle ne risque pas. C'est certain. Celles qui enfreignent les règles seront corvée de rangement !"
    t "(J'ai laissé mon agressivité prendre le dessus avant même que le premier cours ne commence. Je vais me faire passer un savon...)"
    scene bg accueil with fade
    jump scene_8

label scene_8:
    # Dominika rapporte à Agnessa (hors action) la gifle de Tamara
    # Tamara tente de se justifier
    # Le cours commence
    show agnessa neutre at right with moveinright
    a "Mademoiselle Tamara. Venez."
    show viktor neutre at left with moveinleft
    t "Oui ?"
    a "Mademoiselle Dominika vient de m'informer d'une gifle dans les vestiaires. Vous baissez dans mon estime."
    menu:
        t "(Je dois me justifier ! Quitte à inventer une histoire !)"
        "\"Les cours m'ont fatiguée, je suis tendue.\"":
            $ excuses_dominika = True
            t "Ma journée au lycée a été éprouvante. J'ai eu trois tests aujourd'hui ! Je pense avoir réussi l'Histoire et le Russe, mais ce n'est pas du tout le cas de la Chimie."
            t "Représenter des molécules complexes n'est clairement pas ma tasse de thé. C'est simple: soit on y arrive aisément, soit on n'y arrive pas du tout."
            t "Dessiner correctement la molécule \"3-Méthylbutan-1-ol\" ne servira à rien dans la vie professionnelle."
            a "Épargnez-moi votre jargon scientifique."
            a "Je laisse passer pour cette fois. Présentez vos excuses à Mademoiselle Dominika."
            t "Dominika, je suis désolée."
            t "(Pourquoi est-ce que c'est à moi de m'excuser ? Elle m'a provoquée la première !)"
        "\"C'est elle qui a commencé !\"":
            t "C'est elle qui a commencé, Agnessa ! Elle profite de mon premier jour pour me saper le moral ! Dès notre premier échange j'ai su qu'elle ferait tout pour être la meilleure !"
            show agnessa colere
            a "Pas de ça, Mademoiselle Tamara. On n'accuse pas les gens comme ça. Vous serez corvée de rangement après le cours."
            show agnessa neutre
            t "(C'est ce qu'elle voulait, en fait. Rester la chouchoute d'Agnessa. Je suis une menace pour elle.)"
    
    # Présentation de Tamara
    a "Mesdemoiselles, nous avons une nouvelle élève dans notre groupe."
    if excuses_dominika == True:
        a "Tamara Verakova m'a convaincue lors de sa démonstration hier. Certes, sa prestation n'était pas très ambitieuse mais je pense qu'elle est capable de progresser assez vite."
    else:
        a "Tamara Verakova a fait une démonstration satisfaisante hier. Cependant, je suis surprise par son comportement."
        a "Mademoiselle Tamara, j'espère que votre attitude changera assez vite."

    a "Présentez-vous."
    t "Je suis Tamara. J'ai 16 ans. Je suis actuellement en classe de première au lycée Dostoïevski de Moscou. Ce que j'aime dans la danse classique c'est sa rigueur et sa grâce."
    t "Si vous faites une démonstration devant une personne qui ne connait pas grand-chose à la danse, elle se dira que c'est facile. En réalité, c'est complètement faux. Lever le pied trop haut de 10 centimètres peut gâcher votre prestation."
    a "Merci, Mademoiselle Tamara."
    
    # Cours
    hide viktor at left with moveoutleft
    a "Mesdemoiselles, dirigez-vous vers la barre pour l'échauffement."
    a "Un, deux, trois, quatre et flexion ! L'autre jambe ! Un, deux, trois, quatre et flexion !"
    "Les filles s'exécutent spontanément. Étant la dernière arrivée, Tamara ne sait pas vraiment comment bien s'y prendre."
    "Elle observe vite fait ses camarades, notamment la rigoureuse Dominika. Tamara tente de reproduire le mieux possible les mouvements d'échauffement."
    a "Très bien. Je vais à présent poser une question à Mademoiselle Tamara."
    a "Mademoiselle Tamara, pouvez-vous me dire combien de positions existe-t-il en danse classique ?"
    show viktor neutre at left with moveinleft
    menu:
        t "(Pourquoi me demande-t-elle ça ? Veut-elle me tester encore une fois ? Combien y a-t-il de positions en danse classique ?)"
        "Deux positions":
            t "Il existe deux positions."
        "Trois positions":
            t "Il existe trois positions."
        "Quatre positions":
            t "Il existe quatre positions."
        "Cinq positions":
            $ correct_positions = True
            t "Il existe cinq positions."

    if correct_positions == True:
        a "Très bien."
    else:
        a "Vous en avez oublié. Vos bases techniques ne sont pas suffisantes."
        t "(Quelle bienveillance.)"
        a "Première position: pieds opposés, talons qui se touchent, mains autour de la taille."
        a "Deuxième position: pieds espacés et bras tendus à l'horizontale."
        a "Troisième position: pieds à 90 degrés, talons qui se touchent, bras droit à la verticale."
        a "Quatrième position: pied droit devant, même orientation des pieds et main gauche autour de la taille."
        a "Cinquième position: bras en l'air."

    hide viktor at left with moveoutleft

    "Le cours se passe dans un silence pesant. Seule la voix d'Agnessa se fait entendre dans la salle."
    "Le cours prend fin..."

    a "Mesdemoiselles, vous pouvez aller vous rhabiller. Le prochain cours sera jeudi."
    
    # Corvée de rangement (si variable excuses_dominika est False) - Agnessa parle d'elle en tête-à-tête
    if excuses_dominika == True:
        a "À bientôt."
    else:
        a "Mademoiselle Tamara, vous devez ranger la salle."
        show viktor neutre at left with moveinleft
        t "(Ah oui, j'ai failli oublier ça. À cause de cette sorcière de Dominika, je dois ranger la salle ! Par chance, il n'y a pas trop de matériel.)"
        a "Tamara. J'ai l'impression de me reconnaître en vous."
        t "Oh, vraiment ? En êtes-vous sûre ?"
        t "(Et pourquoi elle m'a juste appelé \"Tamara\" ? C'est étrange.)"
        a "Je me souviens de mon tout premier cours de danse. Je n'avais que 8 ans."
        a "Ma mère voulait que je me trouve une passion et j'ai choisi la danse classique."
        a "Tout comme vous, mes débuts ont été plutôt difficiles. Quand j'étais écolière, les autres filles se moquaient de moi sous prétexte que j'avais pour ambition d'être une danseuse étoile."
        t "Et pourtant la Russie est réputée pour la rigueur de ses programmes de danse classique."
        a "Je suis d'accord."
        a "Je me rappelle toujours du nom de ma première professeure. Nadya Farovski. Elle a pris sa retraite il y a très longtemps puisqu'elle a plus de 80 ans à ce jour."
        a "Je la considérais comme une deuxième mère. Mais elle était très sévère. Je pense que c'est à cause d'elle que je suis plutôt froide et même parfois méchante auprès de vous toutes. J'ai calqué mon comportement sur le sien."
        t "N'ayez aucune crainte, Agnessa. D'ailleurs, je trouve que ce comportement sévère est ce qui a de mieux dans la danse classique. Cette discipline n'est pas à prendre à la légère."
        a "Vous êtes très mature pour votre âge."
        a "Les années ont passé et j'ai continué à suivre des cours de danse."
        a "Jusqu'à ce que je remporte un concours national face à près de 700 autres concurrentes de mon âge. J'ai été sélectionnée pour intégrer une troupe qui se produit dans le monde."
        a "J'ai toujours chez moi les articles de presse au sujet de ma première représentation."
        t "Agnessa, cela ne fait que 24 heures qu'on se connaît ; mais notre conversation m'a permis de comprendre qui vous êtes réellement. Une femme merveilleuse."
        a "Tamara, merci. Vous pouvez y aller."
        t "À bientôt."
        t "(Hé bien, je ne m'attendais pas à ce qu'Agnessa me raconte sa vie alors que j'étais corvée de rangement ! Néanmoins, j'ai appris beaucoup de choses sur elle.)"
        t "(Celle que j'aurais considéré comme la Cruella d'Enfer du ballet à notre première rencontre serait en réalité l'ange de la danse classique. Touchant.)"
    
    hide viktor at right with moveoutright
    scene bg rdc with fade
    jump scene_9

label scene_9:
    # Viktor rentre chez lui et ment au sujet de son cours
    show maman at left with moveinleft
    show viktor neutre at right with moveinright
    "Viktor est de retour chez lui. Sa mère et Pavel l'attendaient."
    m "Alors ? Comment s'est passé ton tout premier cours d'échecs ?"
    v "C'était passionnant. Monsieur Meryshev nous a expliqués très précisément ce qu'était un zugzwang."
    v "(Je n'aurais pas dû parler d'un terme hyper compliqué. Ce n'était que mon premier cours ! Heureusement, j'ai quand même fait une recherche rapide à ce sujet au préalable.)"
    m "Tu sais que je ne joue pas aux échecs. Pourrais-tu me l'expliquer rapidement ?"
    v "Le zugzwang est une combinaison de deux mots allemands. Un joueur est en zugzwang lorsqu'il doit jouer mais que chaque coup possible ne ferait qu'aggraver sa situation."
    m "Donc un joueur en zugzwang est en très mauvaise posture."
    v "On peut dire ça."
    m "Je viens seulement de le remarquer."
    m "Tu es en sueur."
    v "(Et fichtre. Je me suis dépensé tant que ça durant le cours de danse ? Je n'avais pas réalisé que c'était physique à ce point.)"
    v "Je suis rentré en courant. J'avais envie de me dépenser."
    "Encore une fois, Viktor et sa mère se régalent du repas préparé par Pavel. Viktor part dans sa chambre pour réfléchir sur le cours des événements."
    hide viktor with moveoutright
    scene bg chambre with fade

    jump scene_10

label scene_10:
    # Viktor est dans sa chambre et ne supporte plus le fait de mentir à tous
    # Il se demande s'il doit révéler son secret ou pas
    # Après réflexion, il décide d'attendre encore un peu
    show viktor neutre at center with dissolve
    v "C'est certain, j'aime bien le ballet. Mais est-il encore nécessaire de mentir sur mon identité ?"
    show viktor doute
    v "J'ai menti à tout le monde."
    v "J'ai menti à maman et à Pavel en disant que je m'étais inscrit à une école d'échecs."
    if ordre_verifie == False:
        v "À Agnessa aussi, à cause de la gaffe sur le chèque."
    v "J'ai menti pour rejoindre l'école de danse. Et c'est encore plus grave. J'ai menti sur mon sexe. J'ai profité de la naïveté des filles pour m'intégrer parmi elles."
    v "Dominika a d'énormes doutes à mon sujet. Sa remarque dans les vestiaires m'a vraiment fait peur:"
    d "\"Tu es en fait un garçon déguisé en fille ou vice-versa ?\""
    v "Leur dire la vérité ou pas ne dépend que de moi. Mais de toute façon, elle sera révélée un jour ou l'autre."

    menu:
        v "C'est le moment de prendre une décision importante: faut-il que je révèle à tout le monde mon terrible secret ? Ou dois-je attendre encore un peu avant de le faire ?"
        "Garder le secret":
            show viktor neutre
            "C'est mieux comme ça pour tout le monde."
        "Réveler le secret":
            "Ça va être difficile à faire. J'appréhende terriblement la réaction des filles."
            menu:
                v "Je peux encore faire marche arrière."
                "Décider de garder le secret":
                    show viktor neutre
                    v "Je pense avoir pris la bonne décision, en fait."
                "Révéler le secret":
                    $ viktor_revele_secret_anticipe = True
                    v "Je pense savoir comment m'y prendre pour leur faire comprendre. Ça pourrait être un peu extrême, mais au moins elles comprendront assez vite. En revanche, je suis sûr que je me ferai expulser."
                    show viktor neutre

    if viktor_revele_secret_anticipe == False:
        "Après une longue réflexion, Viktor a finalement décidé de ne pas révéler sa double identité tout de suite. Il préfère attendre un peu."
    else:
        "Viktor a pris la décision d'avouer sa double identité lors du prochain cours."

    # Fondu au noir, les cours du mardi, mercredi et jeudi passent tranquillement
    "Les journées suivantes au lycée sont tranquilles. Viktor est un élève intelligent et passionné par l'histoire de la Russie. Par contre, il n'est pas super intéressé par les Rois de France."
    "Pourquoi y a-t-il eu presque 20 monarques prénommés Louis sur plus de 11 siècles ? Viktor l'a déjà oublié."
    "Nous sommes jeudi."
    scene bg izmailovo with fade

    jump scene_11

label scene_11:
    if viktor_revele_secret_anticipe == False:
        show viktor neutre at left with moveinleft
        "Viktor se dirige sereinement à l'école de danse."
    else:
        show viktor doute at left with moveinleft
        "Viktor a la boule au ventre. Il a prévu de révéler son identité transgenre aux filles."

    "Les filles attendent à l'extérieur. Comme d'habitude, Dominika est toujours aussi \"sympathique\" avec les autres. C'est une nouvelle fois Lucy qui va s'attirer les foudres de la Princesse Yurlova."
    show viktor neutre
    show lucy colere at center with moveinleft
    show dominika neutre at right with moveinright
    l "Arrête avec tes manières de princesse ! Tu mérites de te faire enlever par une tortue géante cracheuse de feu ! Et qui plus est, un plombier rouge un peu grassouillet viendra te sauver !"
    show dominika colere
    d "GRAAAAAAAAAAAAAAAAAH !"
    t "(C'est encore une fois assez agité. Lucy n'a pas supporté la menace de Dominika au cours précédent et lui rend la pareille. Dominika ne s'attendait pas à ce que sa victime se rebelle. Amusant, et mérité.)"
    t "Salut."
    show lucy neutre
    l "Oh, salut Tamara."
    d "Pfeuh."
    hide dominika at right with moveoutright
    t "(Ça doit être sa façon à elle de dire bonjour quand elle est en colère. Je ne vais pas insister.)"
    show agnessa neutre at right with moveinright
    a "Mesdemoiselles, bonjour. Entrez."
    scene bg vestiaire with fade

    jump scene_12

label scene_12:
    # Dans les vestiaires, scène ordinaire
    # Sauf si Viktor a décidé d'avouer: mauvaise fin
    show viktor neutre at left with moveinleft
    show lucy neutre at center with moveinright
    l "Tamara, ça va ? Tu as l'air perdue dans tes pensées."
    t "Oui, ça va. Je me demande comment va se passer ce cours."
    show dominika neutre at right with moveinright
    d "Tu vas encore te ridiculiser. J'en suis sûre."
    t "Je commence à te connaître. Je ne me ferai plus avoir."
    
    if viktor_revele_secret_anticipe == True:
        jump scene_bad
    
    "Les filles partent vers la salle de cours."
    scene bg accueil with fade

    jump scene_13

label scene_13:
    # Deuxième cours, scène ordinaire
    show agnessa neutre at right with moveinright
    a "Mesdemoiselles. J'ai une annonce de la plus haute importance à vous faire."
    a "J'ai appris par l'opéra de Moscou qu'ils recherchent actuellement une danseuse pour une représentation d'ici trois semaines."
    a "Je ne peux pas vous positionner toutes les huit. C'est pour cela que je vais organiser une compétition."
    a "Vous allez chacune faire une démonstration libre de deux à trois minutes. Je vous évaluerai sur la difficulté de votre programme, la qualité technique ainsi que sur la prestance. Je vous laisse carte blanche pour la musique."
    a "Vous avez les deux heures de cette séance pour préparer votre programme en détail. Je vais vous chercher du papier pour prendre des notes. Je vous autorise à repartir avec elles pour retravailler votre programme chez vous."
    a "Mademoiselle Tamara, comme vous êtes la dernière arrivée, je vous autorise à ne pas prendre part à cette compétition et à quitter la séance. Vous reviendrez la semaine prochaine."
    show viktor neutre at left with moveinleft
    t "Je compte rester. Je vais profiter de cette compétition pour vous montrer ce que je vaux."
    a "Faites comme vous voulez."
    hide agnessa with moveoutright
    t "(Et bien. Je ne m'attendais pas à ça. Participer à une compétition alors que ce n'est que ma deuxième séance !)"
    "Agnessa remet des feuilles à chaque fille. Chacune s'isole dans la salle et prépare sa prestation."
    "Dominika est très inspirée. On peut lire une liste interminable de mouvements sur sa feuille. Son programme est ambitieux."
    "Arabesques, assemblés, pas de basque, battements, pas de bourrée, entrechats, jetés, sissonnes, soubresauts et autres mouvements apparaissent au fil du temps sur les notes manuscrites."
    "Tamara est en grande difficulté. Elle sait qu'elle doit faire une prestation à la fois complexe et de qualité."
    "Tamara constate que Lucy vient vers elle."
    show lucy neutre at center with moveinright
    l "Alors ? Tu as l'air perdue dans tes pensées."
    t "Oui. Je n'ai aucune expérience en ballet. Je ne connais quasiment aucun mouvement. Je n'arrive pas à comprendre pourquoi Agnessa m'a intégré parmi vous alors que ma prestation était tellement basique..."
    l "Elle pense que tu peux encore progresser. Que voudrais-tu comme style de programme ?"
    t "Je voudrais un programme un peu lent sans être soporifique."
    l "Les arabesques sont une bonne base. Passe-moi ta feuille, je vais dessiner ça."
    "Lucy prend la feuille de Tamara et dessine en détail une arabesque, en entourant les éléments importants de ce mouvement."
    l "Tu vois, la jambe que tu lèves doit être parfaitement parallèle au sol. Pareil pour le bras que tu tendras vers l'arrière."
    "Lucy en profite également pour rajouter tout plein d'autres mouvements. Tamara est déstabilisée."
    hide lucy with moveoutright
    "Une heure plus tard, Tamara commence à reproduire les mouvements sur sa feuille. Pas mal pour un niveau scolaire mais insuffisant pour une compétition. Agnessa n'aurait pas mis plus de 3 sur 10."
    "Agnessa se dirige vers Tamara."
    show agnessa neutre at right with moveinright
    a "Mademoiselle Tamara, comment vous en sortez-vous ?"
    t "Ce n'est pas facile. Je ne connais que peu de mouvements. Heureusement que Lucy est venue m'éclairer un peu."
    a "C'est bien. Je vous conseille d'apprendre d'autres mouvements chez vous et de continuer à vous entraîner. Je crois en vous."
    hide agnessa with moveoutright

    if excuses_dominika == False:
        t "(Ah ? Elle est encore une fois bienveillante.)"
    else:
        t "(Sa bienveillance m'a pris au dépourvu. Elle est gentille, malgré les apparences.)"

    "La séance se termine."
    a "Mesdemoiselles, je vous suggère de continuer à vous entraîner chez vous. Vous passerez par ordre alphabétique."
    a "Vous pouvez y aller."

    "Tamara et les autres filles retournent aux vestiaires. La compétition est dans tous les esprits."
    hide viktor with moveoutright

    # TODO: Fondu au noir vers chez Viktor, avant la téléportation
    scene bg chambre with fade
    jump scene_14

label scene_14:
    show viktor neutre at center with dissolve
    v "J'ai tout un programme à concevoir. Trouver la musique me permettra d'avoir une base pour mes mouvements et le style général de mon programme."
    v "\"♫ Remember my name ! I'm gonna live forever ! I'm gonna learn how to fly !\""
    v "Pourquoi est-ce que j'ai le thème de Fame dans ma tête ?"
    v "Maman aimait beaucoup regarder des comédies musicales. Leurs chansons me sont rentrées dans la tête et n'en sont jamais ressorties."
    v "Danser sur Fame n'est pas une si mauvaise idée que ça... À condition que j'envisage de jouer un personnage majeur pour le remake de Glee... S'il existe un jour."
    v "Attends un peu."
    v "J'ai récemment écouté une chanson française qui m'a donné des frissons. Ça pourrait être pas mal à insérer dans une chorégraphie de ballet. Par contre je n'ai pas le titre en tête, juste quelques paroles du refrain..."
    v "\"♫ Je t'aime, comment on fait je t'aime, plus que tu m'aimes je t'aime, comment revêtir le ciel de la couleur de nos veines...\""
    v "Je vais télécharger la chanson."
    "Note du créateur" "Je ne cautionne pas le téléchargement illégal de chansons. Merci de ne pas reproduire tout ce que vous voyez derrière votre ordinateur !"
    "Note du créateur" "Par contre, j'avoue aimer celle-ci. Une chanson française dont le pseudonyme de l'interprète veut dire \"Étoile\" en japonais. Curieux."
    v "Ensuite, j'ouvre mon logiciel d'édition sonore."
    show bg chambre audacity with dissolve
    pause 1.0
    v "J'importe la chanson."
    v "Je ne vais pas toucher au tempo ou à la hauteur de la chanson."
    v "Par contre, je vais utiliser l'option pour retirer la voix de Hoshi..."
    v "Voyons ça..."
    v "..."
    v "Génial."
    v "Il faut que je liste vite fait les mouvements les plus pertinents pour une chanson émouvante."
    "Trouver le programme parfait prend énormément de temps. Il est deux heures du matin. Viktor finalise son programme et semble satisfait, mais épuisé. Il profitera des jours suivants pour s'entraîner... en cachette."
    scene bg vestiaire with fade
    jump scene_15

label scene_15:
    # Les filles passent chacune leur tour
    # Agnessa demande à ce que Tamara passe en dernier
    show viktor neutre at left with moveinleft
    "Le jour J est arrivé pour Tamara. C'est aujourd'hui qu'elle et les autres filles vont se présenter devant Agnessa pour le poste de danseuse."
    "Agnessa a prévu de faire passer les filles par ordre alphabétique. Tamara passera en avant-dernier, avant Dominika."
    "Toutes les filles attendent leur tour dans les vestiaires. Toutes les dix minutes, une fille est appelée. Les vestiaires se vident petit à petit. Personne ne sait ce qui se passe dans la salle de danse."
    "Seules les musiques des programmes peuvent être entendues. Silence pesant. Pression énorme."
    "Dominika s'adresse à Tamara."
    show dominika neutre at right with moveinright
    d "Tu as tout de même décidé de participer à cette compétition. Soit tu es folle, soit tu essayes de frimer."
    d "Mais quoi qu'il en soit, ça sera moi la gagnante."
    t "On verra."
    show dominika at center with moveinright
    "Agnessa entre dans les vestiaires."
    show agnessa neutre at right with moveinright
    a "Mesdemoiselles, je voudrais qu'on inverse l'ordre de passage."
    a "Je voudrais faire passer Mademoiselle Tamara en dernier. J'ai quelque chose à lui dire en tête-à-tête."
    a "Mademoiselle Dominika, venez."
    d "D'accord, Agnessa."
    hide agnessa with moveoutright
    pause 1.0
    hide dominika with moveoutright
    "Tamara regarde Dominika partir avec Agnessa. Elle en profite pour réfléchir."
    t "Alors... C'est simple. Je me ridiculiserai. Je ne suis pas assez expérimentée pour faire une bonne prestation. Certes, Agnessa pourrait aimer, mais je ne gagnerai pas."
    t "Si je ne gagne pas, j'avouerai mon secret."
    "Les minutes défilent. Tamara commence à s'inquiéter."
    "Le moment fatidique est arrivé."
    show agnessa neutre at right with moveinright
    a "Tamara, à vous."
    hide agnessa with moveoutright
    hide viktor with moveoutright
    pause 1.0
    scene bg accueil with fade
    jump scene_16

label scene_16:
    # Agnessa dit à Tamara qu'elle connait son secret mais ne lui en veut pas
    show viktor neutre at left with moveinleft
    show agnessa neutre at right with moveinright
    a "Avant de commencer, j'ai quelque chose à te dire."
    a "Je connais ton secret."
    show viktor doute
    t "..."
    t "Je le savais. Je savais que je me ferais démasquer. Mais comment avez-vous su que j'étais un garçon ?"
    a "Mon fils était comme toi. Il ne se reconnaissait pas en tant que garçon et a donc décidé de prendre des hormones pour être une fille."
    a "Lorsque toi et moi nous sommes rencontrés pour la première fois, j'avais l'impression de le revoir."
    t "(Hé bien, quelle était la probabilité que je me fasse démasquer sans subir aucune moquerie ou reproche ? Infinitésimale.)"
    a "Mon fils est désormais ma fille. Luka s'appelle désormais Barbara. Elle est flûtiste au conservatoire de Moscou et elle est mariée."
    show viktor neutre
    t "Je ne m'appelle pas Tamara. Je m'appelle Viktor. Je suis un lycéen ordinaire."
    v "Par chance, les autres ne profitent pas de ma transidentité pour me harceler. Au contraire, ils me considèrent comme une personne ordinaire."
    a "Veux-tu toujours me présenter ton programme ?"
    v "Oui."
    a "Mets ta clé USB dans l'ordinateur et lance ta musique."
    hide agnessa with moveoutright
    "Agnessa part s'asseoir devant ses notes. Viktor se dirige vers l'ordinateur et insère sa clé USB."
    "La musique part... Viktor se met face à Agnessa et commence son programme."
    "Des gestes lents et grâcieux."
    "Des positions tenues."
    "Un grand écart de toute beauté."
    "Un enchaînement final digne d'un professionnel."
    "La musique se dissipe. Un silence pesant se fait entendre."
    "Viktor a-t-il réussi sa prestation ? Il voit Agnessa griffonner ses notes et compter les points."
    "Agnessa lève la tête et regarde Viktor attentivement. Le verdict va sans doute tomber."
    show agnessa neutre at right with moveinright
    a "Viktor."
    play music "/audio/Intro - Ofelia's Dream (Bensound).ogg" noloop
    queue music "/audio/Loop - Ofelia's Dream (Bensound).ogg"
    a "Je suis sans voix."
    a "Comment as-tu fait pour parvenir à un tel programme ? Il était complexe et tu as réussi avec brio."
    a "Viktor. Tu as eu la meilleure note."
    v "Quoi ! Vous m'avez favorisé !"
    a "Pas du tout. Tu as un talent inné pour la danse. Tu devrais réellement faire carrière dans cet art."
    show viktor triste
    v "Oui... Mais c'est pour une place de danseuse. Pour une fille."
    a "Je leur dirai que tu es un garçon talentueux et que tu pourrais te positionner pour un poste de danseur. Mais rappelle-toi, ce n'était qu'une présélection."
    a "Tu devras encore faire tes preuves à l'opéra. Mais je crois en toi."
    a "Je positionnerai Dominika sur le poste de danseuse car c'est elle qui est arrivée deuxième. Vous pouvez le faire."
    v "..."
    a "Ne pleure pas. Je révelerai à tout le monde ta transidentité. Les filles ne t'en voudront pas. Au contraire, elles t'envieront."
    v "J'ai menti à ma mère et à mon beau-père."
    a "Je leur parlerai de Barbara. Ils comprendront."
    "Viktor serre Agnessa dans ses bras."
    # Fondu au noir
    scene bg cathedral with fade
    jump scene_good

label scene_good:
    # Bonne fin: Agnessa aide Viktor à se libérer de son mensonge
    "Agnessa a accompagné Viktor chez lui et s'est longuement entretenue avec sa mère et Pavel."
    "Très touchés, ils ont laissé Viktor se positionner pour le rôle de danseur."
    "Encouragé par Agnessa, Viktor a époustouflé le jury qui l'a intégré dans le ballet."
    "La suite, vous la connaissez déjà."
    "Fin heureuse."
    jump credits

label scene_bad:
    # Mauvaise fin: Viktor montre son sexe et quitte l'école de son propre gré
    t "(C'est le moment.)"
    show viktor nu at left with hpunch
    show lucy gene
    show dominika gene
    pause 0.5
    play sound "/audio/Hurlements.mp3"
    pause 0.1
    hide lucy with moveoutright
    hide dominika with moveoutright
    "Tamara abaisse ses sous-vêtements et dévoile quelque chose auquel les filles ne s'attendaient pas du tout à voir ici. Tamara est partie. Viktor est revenu."
    "Note du créateur" "Je vous déconseille vivement de faire la même chose que Viktor dans la vraie vie. Merci de ne pas reproduire tout ce que vous voyez derrière votre ordinateur !"
    "Bien entendu, la scène gêne terriblement les autres filles qui ont quitté précipitamment les vestiaires en hurlant."
    "Par contre, Viktor sait qu'il doit partir de l'école de danse."
    show viktor neutre
    pause 1.0
    hide viktor with moveoutleft
    "Son rêve aura été très bref, mais il s'est libéré de son mensonge."
    "De toute façon, il peut toujours intégrer l'école d'échecs de Monsieur Meryshev."
    "Fin mauvaise... mais pas tant que ça."
    "En revanche, vous avez changé le cours du temps ! Puisque Viktor a abandonné son projet de danseur étoile, ce qu'il nous avait raconté à l'introduction n'aura donc jamais lieu !"
    jump credits